Registrarse

[Otros] [poryscript] Ejemplo de script de nivel en decompilación

Jack Johnson

No hago encargos ni respondo dudas por privado.
Miembro del equipo
Colaborador
Como ya sabéis, participé en el Concurso de Scripts de 2020, y, pese a no haber recibido ningún premio, quedé bastante satisfecho con este script, el cual tiene un poco de todo. Como creo que puede ayudar a los nuevos a aprender a usar poyscript, un lenguaje de scripts un poco más avanzado que el que se usa por defecto, voy a liberar aquí su código fuente.


JavaScript:
const VALUE_AT_START    = 11
const END_SCRIPT        = VALUE_AT_START + 1

const X_CAM_BATALLA     = 10
const Y_CAM_BATALLA     = 25
const X_CAM_METEORITO   = 29
const Y_CAM_METEORITO   = 5

const CAMERA_ID = OBJ_EVENT_ID_CAMERA
const PLAYER_ID = OBJ_EVENT_ID_PLAYER

const POOCH_NPC_ID      = 1
const KIRLIA_NPC_ID     = 2
const GALLADE_NPC_ID    = 3
const CIENTIFICO_NPC_ID = 4
const HOGAN_NPC_ID      = 5
const ZEL_NPC_ID       = 6
const PROF_NPC_ID       = 7
const HOGAN2_NPC_ID     = 8
const ZEL2_NPC_ID      = 9

mapscripts LagoTerral_MapScripts {
    MAP_SCRIPT_ON_RESUME {
        // setstepcallback(STEP_CB_TRUCK)
        // end
    }
    MAP_SCRIPT_ON_FRAME_TABLE [
            VAR_PUEBLO_ORIGEN_STATE_INTRO_STATE, VALUE_AT_START
            {
                lock
                clearflag(FLAG_HIDE_HOGAN_LAGO_TERRAL)
                setflag(FLAG_HIDE_POKES_LAGO_TERRAL)
                setflag(FLAG_HIDE_ZEL_ZEL_LAGO_TERRAL)
                removeobject(HOGAN2_NPC_ID)
                setvar(VAR_0x8004, X_CAM_BATALLA)
                setvar(VAR_0x8005, Y_CAM_BATALLA)
                fadescreen(FADE_TO_BLACK)
                special(TeleportCamera)
                fadeoutbgm(1)
                delay(16)
                playbgm(MUS_MT_CHIMNEY, 0)
                fadescreen(FADE_FROM_BLACK)
                // PRESENTACIÓN
                delay(10)
                applymovement(HOGAN_NPC_ID, LagoTerral_Movimiento_Hogan1)
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_ExclamationMark)
                waitmovement(0)
                msgbox(LagoTerral_Texto_Hogan1)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico1)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico1)
                closemessage
                msgbox(LagoTerral_Texto_Hogan2)
                applymovement(HOGAN_NPC_ID, LagoTerral_Movimiento_Hogan2)
                waitmovement(HOGAN_NPC_ID)
                closemessage
                applymovement(HOGAN_NPC_ID, LagoTerral_Movimiento_Hogan3)
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_ExclamationMark)
                waitmovement(0)
                msgbox(LagoTerral_Texto_Hogan3)
                closemessage
                applymovement(HOGAN_NPC_ID, LagoTerral_Movimiento_Hogan4)
                waitmovement(HOGAN_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico2)
                closemessage
                applymovement(HOGAN_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(HOGAN_NPC_ID)
                msgbox(LagoTerral_Texto_Hogan5)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico2)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico3)
                closemessage
                msgbox(LagoTerral_Texto_Hogan6)
                applymovement(HOGAN_NPC_ID, LagoTerral_Movimiento_Hogan5)
                closemessage
                waitmovement(HOGAN_NPC_ID)
                removeobject(HOGAN_NPC_ID)
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceRight)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico4)
                closemessage
                delay(30)
                fadescreen(FADE_TO_BLACK)
                fadedefaultbgm
                special(ReturnCameraToPlayer)
                fadescreen(FADE_FROM_BLACK)
                // ENCUENTRO CON HOGAN
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Prof1)
                applymovement(PLAYER_ID, LagoTerral_Movimiento_Player1)
                waitmovement(0)
                msgbox(LagoTerral_Texto_Prof1)
                closemessage
                addobject(HOGAN2_NPC_ID)
                applymovement(HOGAN2_NPC_ID, LagoTerral_Movimiento_Hogan6)
                waitmovement(HOGAN2_NPC_ID)
                playse(SE_EFFECTIVE)
                applymovement(HOGAN2_NPC_ID, LagoTerral_Movimiento_Hogan7)
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Prof2)
                applymovement(PLAYER_ID, Common_Movement_ExclamationMark)
                waitmovement(0)
                delay(15)
                msgbox(LagoTerral_Texto_Hogan7)
                closemessage
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Prof3)
                applymovement(PLAYER_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(0)
                msgbox(LagoTerral_Texto_Prof2)
                closemessage
                applymovement(HOGAN2_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(HOGAN2_NPC_ID)
                msgbox(LagoTerral_Texto_Hogan8)
                closemessage
                applymovement(HOGAN2_NPC_ID, LagoTerral_Movimiento_Hogan8)
                waitmovement(HOGAN2_NPC_ID)
                playse(SE_EXIT)
                setflag(FLAG_HIDE_HOGAN_LAGO_TERRAL)
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceRight)
                applymovement(PLAYER_ID, Common_Movement_WalkInPlaceLeft)
                waitmovement(0)
                delay(15)
                msgbox(LagoTerral_Texto_Prof3)
                closemessage
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(PROF_NPC_ID)
                msgbox(LagoTerral_Texto_Prof4)
                closemessage
                // DIALOGO Y DESAPARICIÓN DEL PROFESOR
                setobjectmovementtype(CIENTIFICO_NPC_ID, MOVEMENT_TYPE_FACE_UP)
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Prof4)
                applymovement(PLAYER_ID, LagoTerral_Movimiento_Player2)
                waitmovement(0)
                special(SpawnCameraObject)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam1)
                waitmovement(CAMERA_ID)
                delay(16)
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_ExclamationMark)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico5)
                closemessage
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(PROF_NPC_ID)
                msgbox(LagoTerral_Texto_Prof5)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico6)
                closemessage
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Prof5)
                waitmovement(PROF_NPC_ID)
                playbgm(MUS_ENCOUNTER_MAGMA, 0)
                msgbox(LagoTerral_Texto_Prof6)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico3)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico7)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico7_2)
                closemessage
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Cientifico3)
                waitmovement(PROF_NPC_ID)
                msgbox(LagoTerral_Texto_Prof7)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico4)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico8)
                closemessage
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Prof6)
                waitmovement(PROF_NPC_ID)
                msgbox(LagoTerral_Texto_Prof8)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico4)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico9)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico3)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico9_2)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico5)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico10)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico11)
                closemessage
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(PROF_NPC_ID)
                msgbox(LagoTerral_Texto_Prof9)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico6)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico12)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico13)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceRight)
                waitmovement(CIENTIFICO_NPC_ID)
                addobject(KIRLIA_NPC_ID)
                playse(SE_WARP_OUT)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Aparecer)
                waitmovement(KIRLIA_NPC_ID)
                playmoncry(SPECIES_KIRLIA, 0)
                waitmoncry
                msgbox(LagoTerral_Texto_Cientifico14)
                closemessage
                applymovement(PROF_NPC_ID, Common_Movement_ExclamationMark)
                waitmovement(PROF_NPC_ID)
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceUp)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Kirlia_1)
                waitmovement(KIRLIA_NPC_ID)
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Prof10)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Kirlia_2_1)
                waitmovement(KIRLIA_NPC_ID)
                playse(SE_BIKE_HOP)
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceLeft)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Kirlia_2_2)
                waitmovement(KIRLIA_NPC_ID)
                playse(SE_BIKE_HOP)
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceUp)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Kirlia_2_3)
                waitmovement(KIRLIA_NPC_ID)
                playse(SE_BIKE_HOP)
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceRight)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Kirlia_2_4)
                waitmovement(KIRLIA_NPC_ID)
                playse(SE_BIKE_HOP)
                waitse
                closemessage
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(PROF_NPC_ID)
                addobject(POOCH_NPC_ID)
                playse(SE_BALL_OPEN)
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Pooch_1)
                waitmovement(POOCH_NPC_ID)
                playmoncry(SPECIES_POOCHYENA, 0)
                waitmoncry
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceLeft)
                waitmovement(PROF_NPC_ID)
                msgbox(LagoTerral_Texto_Prof11)
                closemessage
                applymovement(POOCH_NPC_ID, Common_Movement_ExclamationMark)
                applymovement(PROF_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(POOCH_NPC_ID)
                delay(15)
                playmoncry(SPECIES_POOCHYENA, 0)
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Pooch_2)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Kirlia_3)
                waitmovement(POOCH_NPC_ID)
                closemessage
                msgbox(LagoTerral_Texto_Prof12)
                playse(SE_WARP_IN)
                applymovement(KIRLIA_NPC_ID, LagoTerral_Movimiento_Desaparecer)
                applymovement(PROF_NPC_ID, LagoTerral_Movimiento_Desaparecer)
                waitmovement(0)
                closemessage
                removeobject(PROF_NPC_ID)
                removeobject(KIRLIA_NPC_ID)
                // INICIO COMBATE
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Pooch_3)
                waitmovement(POOCH_NPC_ID)
                playmoncry(SPECIES_POOCHYENA, 0)
                waitmoncry
                msgbox(LagoTerral_Texto_Cientifico15)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico7)
                waitmovement(CIENTIFICO_NPC_ID)
                fadeoutbgm(1)
                playbgm(MUS_C_VS_LEGEND_BEAST, 0)
                fadescreen(FADE_TO_WHITE)
                fadescreen(FADE_FROM_WHITE)
                fadescreen(FADE_TO_WHITE)
                fadescreen(FADE_FROM_WHITE)
                fadescreen(FADE_TO_WHITE)
                fadescreen(FADE_FROM_WHITE)
                delay(16)
                msgbox(LagoTerral_Texto_Cientifico16)
                closemessage
                addobject(GALLADE_NPC_ID)
                playse(SE_BALL_OPEN)
                applymovement(GALLADE_NPC_ID, LagoTerral_Movimiento_Gallade_1)
                waitmovement(GALLADE_NPC_ID)
                playmoncry(SPECIES_GALLADE, 0)
                waitmoncry
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam2)
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico8)
                waitmovement(CIENTIFICO_NPC_ID)
                // pooch placaje
                msgbox(format("¡Poochyena usó Placaje!"))
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Placaje_1)
                waitmovement(POOCH_NPC_ID)
                closemessage
                msgbox(format("¡Gallade usó Protección!"))
                // gallade protect
                applymovement(GALLADE_NPC_ID, Common_Movement_WalkInPlaceDown)
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Placaje_2)
                playse(SE_M_VITAL_THROW)
                dofieldeffectsparkle(10, 21, 0)
                waitfieldeffect(FLDEFF_SPARKLE)
                playse(SE_FAILURE)
                msgbox(format("¡Gallade se ha protegido!"))
                closemessage
                delay(15)
                // pooch gruñido
                msgbox(format("¡Poochyena usó Aullido!"))
                playmoncry(SPECIES_POOCHYENA, 0)
                applymovement(POOCH_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(POOCH_NPC_ID)
                msgbox(format("¡El Ataque de Poochyena subió!"))
                playse(SE_M_STAT_INCREASE)
                waitse
                closemessage
                delay(15)
                // gallade onda certera
                msgbox(format("¡Gallade usó Onda Certera!"))
                closemessage
                playse(SE_M_DETECT)
                dofieldeffectsparkle(10, 21, 0)
                waitfieldeffect(FLDEFF_SPARKLE)
                setvar(VAR_0x8004, 120) // orb x
                setvar(VAR_0x8005, 64)  // orb y
                setvar(VAR_0x8006, 0)   // orb color = red
                special(DoOrbEffectCustom) // Special nuevo
                delay(30)
                playse(SE_SUPER_EFFECTIVE)
                applymovement(GALLADE_NPC_ID, LagoTerral_Movimiento_OndaCertera)
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Damage)
                dofieldeffectsparkle(10, 23, 0)
                waitfieldeffect(FLDEFF_SPARKLE)
                waitmovement(0)
                special(FadeOutOrbEffect)
                waitstate
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam3)
                waitmovement(CAMERA_ID)
                msgbox(format("¡Es muy eficaz!"))
                closemessage
                msgbox(format("¡Poochyena se debilitó!"))
                playmoncry(SPECIES_POOCHYENA, 1)
                waitmoncry
                playse(SE_FAINT)
                waitse
                applymovement(POOCH_NPC_ID, Common_Movement_WalkInPlaceDown)
                closemessage
                playfanfare(MUS_AWAKEN_LEGEND)
                // DESPEDIDA CIENTIFICO
                applymovement(PLAYER_ID, LagoTerral_Movimiento_Player_3)
                waitmovement(PLAYER_ID)
                applymovement(POOCH_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(POOCH_NPC_ID)
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico_9)
                waitmovement(CIENTIFICO_NPC_ID)
                playse(SE_BALL_OPEN)
                applymovement(GALLADE_NPC_ID, LagoTerral_Movimiento_Gallade_2)
                waitmovement(GALLADE_NPC_ID)
                removeobject(GALLADE_NPC_ID)
                delay(15)
                waitfanfare
                playbgm(MUS_ABNORMAL_WEATHER, 0)
                applymovement(CIENTIFICO_NPC_ID, LagoTerral_Movimiento_Cientifico_10)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico17)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceRight)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico18)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico19)
                closemessage
                applymovement(CIENTIFICO_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(CIENTIFICO_NPC_ID)
                msgbox(LagoTerral_Texto_Cientifico20)
                closemessage
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_Up)
                waitmovement(CAMERA_ID)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_Up)
                waitmovement(CAMERA_ID)
                delay(15)
                setfieldeffectargument(0, 1)
                dofieldeffect(FLDEFF_NPCFLY_OUT)
                delay(15)
                removeobject(CIENTIFICO_NPC_ID)
                waitfieldeffect(FLDEFF_NPCFLY_OUT)
                delay(15)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_Down)
                waitmovement(CAMERA_ID)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_Down)
                waitmovement(CAMERA_ID)
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Pooch_4)
                waitmovement(POOCH_NPC_ID)
                playmoncry(SPECIES_POOCHYENA, 0)
                waitmoncry
                msgbox(LagoTerral_Texto_Player)
                closemessage
                applymovement(POOCH_NPC_ID, LagoTerral_Movimiento_Pooch_5)
                waitmovement(POOCH_NPC_ID)
                removeobject(POOCH_NPC_ID)
                setflag(FLAG_HIDE_POKES_LAGO_TERRAL)
                special(RemoveCameraObject)
                // DIALOGO ZEL
                addobject(ZEL_NPC_ID)
                applymovement(ZEL_NPC_ID, LagoTerral_Movimiento_Zel_1)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_1)
                closemessage
                setvar(VAR_0x8004, 10)
                setvar(VAR_0x8005, 24)
                fadescreen(FADE_TO_BLACK)
                special(TeleportCamera)
                delay(16)
                special(ReturnCameraToPlayer)
                applymovement(ZEL_NPC_ID, LagoTerral_Movimiento_Zel_2)
                waitmovement(ZEL_NPC_ID)
                fadescreen(FADE_FROM_BLACK)
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_2)
                closemessage
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceRight)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_3)
                closemessage
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_4)
                closemessage
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_5)
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_6)
                closemessage
                applymovement(ZEL_NPC_ID, LagoTerral_Movimiento_Zel_3)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_7)
                closemessage
                showmoneybox(0, 0, 0)
                special(SaveMoneyToVar0x8005) //Special nuevo
                copyvar(VAR_STOLEN_MONEY_AT_LAKE, VAR_0x8005)
                buffernumberstring(0, VAR_STOLEN_MONEY_AT_LAKE)
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_8)
                closemessage
                applymovement(ZEL_NPC_ID, Common_Movement_QuestionMark)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_8_2)
                closemessage
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(ZEL_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_9)
                closemessage
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceRight)
                waitmovement(ZEL_NPC_ID)
                playse(SE_SHOP)
                removemoney(VAR_STOLEN_MONEY_AT_LAKE, 0)
                updatemoneybox(0, 0)
                msgbox(LagoTerral_Texto_Zel_10)
                waitse
                closemessage
                hidemoneybox
                applymovement(ZEL_NPC_ID, Common_Movement_WalkInPlaceDown)
                waitmovement(ZEL_NPC_ID)
                buffernumberstring(0, VAR_STOLEN_MONEY_AT_LAKE)
                msgbox(LagoTerral_Texto_Zel_11)
                closemessage
                    // INICIO TRAVELLING
                setvar(VAR_0x8004, X_CAM_METEORITO)
                setvar(VAR_0x8005, Y_CAM_METEORITO)
                fadescreen(FADE_TO_BLACK)
                special(TeleportCamera)
                clearflag(FLAG_HIDE_ZEL_ZEL_LAGO_TERRAL)
                addobject(ZEL2_NPC_ID)
                delay(16)
                fadescreen(FADE_FROM_BLACK)
                special(SpawnCameraObject)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_4)
                waitmovement(CAMERA_ID)
                msgbox(LagoTerral_Texto_Zel_12)
                closemessage
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_4)
                waitmovement(CAMERA_ID)
                msgbox(LagoTerral_Texto_Zel_13)
                closemessage
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_5)
                waitmovement(CAMERA_ID)
                special(RemoveCameraObject)
                msgbox(LagoTerral_Texto_Zel_14)
                closemessage
                    // FIN TRAVELLING
                fadescreen(FADE_TO_BLACK)
                special(ReturnCameraToPlayer)
                fadescreen(FADE_FROM_BLACK)
                msgbox(LagoTerral_Texto_Zel_15)
                closemessage
                applymovement(ZEL2_NPC_ID, LagoTerral_Movimiento_Zel_4)
                waitmovement(ZEL2_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_16)
                closemessage
                applymovement(ZEL2_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(ZEL2_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_17)
                closemessage
                applymovement(ZEL2_NPC_ID, LagoTerral_Movimiento_Zel_5)
                waitmovement(ZEL2_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_18)
                closemessage
                giveitem(ITEM_METEORITE)
                closemessage
                applymovement(ZEL2_NPC_ID, LagoTerral_Movimiento_Zel_6)
                waitmovement(ZEL2_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_19)
                closemessage
                applymovement(ZEL2_NPC_ID, Common_Movement_WalkInPlaceUp)
                waitmovement(ZEL2_NPC_ID)
                msgbox(LagoTerral_Texto_Zel_20)
                closemessage
                applymovement(ZEL2_NPC_ID, LagoTerral_Movimiento_Zel_7)
                waitmovement(ZEL2_NPC_ID)
                special(SpawnCameraObject)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_Up)
                waitmovement(CAMERA_ID)
                msgbox(LagoTerral_Texto_Zel_21)
                closemessage
                delay(15)
                setfieldeffectargument(0, 1)
                dofieldeffect(FLDEFF_NPCFLY_OUT)
                delay(15)
                removeobject(ZEL2_NPC_ID)
                waitfieldeffect(FLDEFF_NPCFLY_OUT)
                delay(15)
                applymovement(CAMERA_ID, LagoTerral_Movimiento_Cam_Down)
                waitmovement(CAMERA_ID)
                // FIN
                special(RemoveCameraObject)
                fadedefaultbgm
                getplayerxy(VAR_TEMP_0, VAR_TEMP_1)
                setflag(FLAG_HIDE_ZEL_ZEL_LAGO_TERRAL)
                setflag(FLAG_HIDE_CIENTIFICO_LAGO_TERRAL)
                setflag(FLAG_HIDE_POKES_LAGO_TERRAL)
                setvar(VAR_PUEBLO_ORIGEN_STATE_INTRO_STATE, END_SCRIPT)
                warp(MAP_LAGO_TERRAL, 0xFF, VAR_TEMP_0, VAR_TEMP_1)
                release
                end
            }
    ]
}

text LagoTerral_Texto_Hogan1 {
    format("???: {COLOR BLUE}¡A ver, empollón! ¿Tenéis ya suficiente ciencia?")
}

text LagoTerral_Texto_Cientifico1 {
    format("???: {COLOR GREEN}Todavía no, señor Hogan.\nAdemás, preferiría que se refiera a mí por mi nombre en clave.")
}

text LagoTerral_Texto_Hogan2 {
    format("Hogan: {COLOR BLUE}¡Grrrr! ¡Grrrr!…")
}

text LagoTerral_Texto_Hogan3 {
    format("Hogan: {COLOR BLUE}¡Escúchame, gafas!\n¡Odio que me molesten mientras estoy en el Gimnasio!\p¡Si no tienes nada para mí, me largo al Gimnasio!")
}

text LagoTerral_Texto_Cientifico2 {
    format("???: {COLOR GREEN}Espere. Hay novedades.")
}

text LagoTerral_Texto_Hogan5 {
    format("Hogan: {COLOR BLUE}¡¿Qué?! No tengo todo el día.")
}

text LagoTerral_Texto_Cientifico3 {
    format("???: {COLOR GREEN}He podido refutar las investigaciones del Profesor Quercus.\pTenemos evidencias de su paradero y…")
}

text LagoTerral_Texto_Hogan6 {
    format("Hogan: {COLOR BLUE}¡Cojonudo! ¡Ja ja ja ja ja!")
}

text LagoTerral_Texto_Cientifico4 {
    format("???: {COLOR GREEN}Este maldito Hogan… Ojalá poder deshacerme de él…")
}

text LagoTerral_Texto_Prof1 {
    format("Prof. Quercus: {COLOR BLUE}¡{PLAYER}, se oyen voces al fondo! ¡Asomémonos a ver si averiguamos algo!")
}

text LagoTerral_Texto_Hogan7 {
    format("Hogan: {COLOR BLUE}¿Disculpe, se ha hecho daño?")
}

text LagoTerral_Texto_Prof2 {
    format("Prof. Quercus: {COLOR BLUE}Solo un poco… Nada grave…")
}

text LagoTerral_Texto_Hogan8 {
    format("Hogan: {COLOR BLUE}¡Ja ja ja ja! ¡A la próxima tendré que hacerlo con más fuerza!")
}

text LagoTerral_Texto_Prof3 {
    format("Prof. Quercus: {COLOR BLUE}Vaya… Qué persona tan desagradable…")
}

text LagoTerral_Texto_Prof4 {
    format("Prof. Quercus: {COLOR BLUE}En fin… Sigamos adelante.")
}

text LagoTerral_Texto_Cientifico5 {
    format("???: {COLOR GREEN}Saludos, profesor…")
}

text LagoTerral_Texto_Prof5 {
    format("Prof. Quercus: {COLOR BLUE}¿Quiénes narices sois?")
}

text LagoTerral_Texto_Cientifico6 {
    format("???: {COLOR GREEN}Precisamente nuestros agentes iban a su laboratorio a hacerle una visita, profesor…")
}

text LagoTerral_Texto_Prof6 {
    format("Prof. Quercus: {COLOR BLUE}¿Qu…? ¿Qué…?")
}

text LagoTerral_Texto_Cientifico7 {
    format("???: {COLOR GREEN}Lamentablemente, usted no está allí para recibirles…")
}

text LagoTerral_Texto_Cientifico7_2 {
    format("???: {COLOR GREEN}Lástima… se van a llevar una… decepción…")
}

text LagoTerral_Texto_Prof7 {
    format("Prof. Quercus: {COLOR BLUE}¡Responde! ¿Qué queréis de mí?")
}

text LagoTerral_Texto_Cientifico8 {
    format("???: {COLOR GREEN}Usted lo sabe, ¿no?\nSabe dónde se encuentra… ¿Me equivoco?")
}

text LagoTerral_Texto_Prof8 {
    format("Prof. Quercus: {COLOR BLUE}Yo… ¿por qué iba a contaros nada?")
}

text LagoTerral_Texto_Cientifico9 {
    format("???: {COLOR GREEN}Este hallazgo es maravilloso, no lo puede negar.")
}

text LagoTerral_Texto_Cientifico9_2 {
    format("???: {COLOR GREEN}Mas no llegará mucho más lejos con los medios de los que dispone en su “casucha”.")
}

text LagoTerral_Texto_Cientifico10 {
    format("???: {COLOR GREEN}De modo que le voy a pedir que nos acompañe a nuestras instalaciones, donde dispondrá de todos los recursos que necesite.")
}

text LagoTerral_Texto_Cientifico11 {
    format("???: {COLOR GREEN}Si no es mucha molestia, claro.")
}

text LagoTerral_Texto_Prof9 {
    format("Prof. Quercus: {COLOR BLUE}¡No pienso ir a ningún sitio, rotundamente no!")
}

text LagoTerral_Texto_Cientifico12 {
    format("???: {COLOR GREEN}Qué faena… sus nuevos compañeros le están esperando…")
}

text LagoTerral_Texto_Cientifico13 {
    format("???: {COLOR GREEN}Sería una pena que se queden con las ganas de conocerle…")
}

text LagoTerral_Texto_Cientifico14 {
    format("???: {COLOR GREEN}Kirlia… ¿por qué no acompañas al Profesor a su nuevo Laboratorio?")
}

text LagoTerral_Texto_Prof10 {
    format("Prof. Quercus: {COLOR BLUE}¿Eh…?")
}

text LagoTerral_Texto_Prof11 {
    format("Prof. Quercus: {COLOR BLUE}¿Poochy? ¿Cómo has salido de tu Pokéball?")
}

text LagoTerral_Texto_Prof12 {
    format("Prof. Quercus: {COLOR BLUE}¿Qué coj…?")
}

text LagoTerral_Texto_Cientifico15 {
    format("???: {COLOR GREEN}Criatura… ¿Acaso crees que eres rival para mí?")
}

text LagoTerral_Texto_Cientifico16 {
    format("???: {COLOR GREEN}¡Demuestra quién manda, Gallade!")
}

text LagoTerral_Texto_Cientifico17 {
    format("???: {COLOR GREEN}Joven… ¿Te has perdido?\pEste no es lugar para niños.")
}

text LagoTerral_Texto_Cientifico18 {
    format("???: {COLOR GREEN}Hmmm… ¿Acaso venías con el Profesor?")
}

text LagoTerral_Texto_Cientifico19 {
    format("???: {COLOR GREEN}Pues te volverás sin él.")
}

text LagoTerral_Texto_Cientifico20 {
    format("???: {COLOR GREEN}Mira, no tengo tiempo como para perderlo con presentaciones.\pSi estimas algo tu vida, olvida lo que has visto aquí, ¿entendido?\pHasta nunca, joven.")
}

text LagoTerral_Texto_Player {
    format("Parece que quiere ir a buscar al Profesor por su cuenta.")
}

text LagoTerral_Texto_Zel_1 {
    format("???: {COLOR RED}¡Vaya! ¿Pretendías defender a ese Poochyena tú solo?")
}

text LagoTerral_Texto_Zel_2 {
    format("???: {COLOR RED}Así que te llamas {PLAYER}…")
}

text LagoTerral_Texto_Zel_3 {
    format("???: {COLOR RED}¿Mi nombre? ¡Ju ju ju!")
}

text LagoTerral_Texto_Zel_4 {
    format("???: {COLOR RED}¡No podrías pagar esa información! Ji ji…")
}

text LagoTerral_Texto_Zel_5 {
    format("???: {COLOR RED}No obstante… Podría ofrecerte algo…\pComo por ejemplo…")
}

text LagoTerral_Texto_Zel_6 {
    format("???: {COLOR RED}¡Los planes supersecretos del Team Reborn!")
}

text LagoTerral_Texto_Zel_7 {
    format("???: {COLOR RED}Pero… Todo tiene un precio… Unos…")
}

text LagoTerral_Texto_Zel_8 {
    format("???: {COLOR RED}¡100.000¥!")
}

text LagoTerral_Texto_Zel_8_2 {
    format("???: {COLOR RED}… … …")
}

text LagoTerral_Texto_Zel_9 {
    format("???: {COLOR RED}¿Que solo tienes {STR_VAR_1}¥?")
}

text LagoTerral_Texto_Zel_10 {
    format("???: {COLOR RED}Bueno, supongo que algo es algo.")
}

text LagoTerral_Texto_Zel_11 {
    format("???: {COLOR RED}Bien, atiende. ¡Haz que esos {STR_VAR_1}¥ hayan valido la pena!\p…\pJe je…")
}

text LagoTerral_Texto_Zel_12 {
    format("{COLOR RED}“Este es el Lago Terral. Se llama así porque se encuentra en la Isla Terral.”")
}

text LagoTerral_Texto_Zel_13 {
    format("{COLOR RED}“Esa montaña que ves en el centro… es un Meteorito. De hecho, este Meteorito creó el Lago hace mucho tiempo.”")
}

text LagoTerral_Texto_Zel_14 {
    format("{COLOR RED}“El Team Reborn ha descubierto que el Meteorito emite una radiación muy intensa, la cuál ha afectado a los Pokémon que viven en este Lago, y, quién sabe si en el resto de Eolia.”")
}

text LagoTerral_Texto_Zel_15 {
    format("???: {COLOR RED}Así que, el Team Reborn planea utilizar esa radiación para sus propósitos de dudosa ética.")
}

text LagoTerral_Texto_Zel_16 {
    format("???: {COLOR RED}… ¿Que cómo sé esto?")
}

text LagoTerral_Texto_Zel_17 {
    format("???: {COLOR RED}Esa información te costará un pequeño favor… Ji ji…")
}

text LagoTerral_Texto_Zel_18 {
    format("???: {COLOR RED}Tendrás que llevar este Fragmento de Meteorito al Instituto de Ciencia de Ciudad Vuestroni.")
}

text LagoTerral_Texto_Player_2 {
    format("{PLAYER} obtuvo un Fragmento de Meteorito.")
}

text LagoTerral_Texto_Zel_19 {
    format("???: {COLOR RED}Quizá tengan la tecnología necesaria para adivinar qué trama el Team Reborn…")
}

text LagoTerral_Texto_Zel_20 {
    format("???: {COLOR RED}… o quizá no. ¡Ji ji!")
}

text LagoTerral_Texto_Zel_21 {
    format("???: {COLOR RED}¡Me tengo que ir! Nos veremos muy pronto, {PLAYER}. ¡Antes de lo que imaginas!\p¡Chao… ji ji!")
}

movement LagoTerral_Movimiento_Hogan1 {
    walk_fastest_up
    step_end
}

movement LagoTerral_Movimiento_Cientifico1 {
    lock_facing_direction
    walk_up
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Hogan2 {
    walk_fastest_left
    walk_fastest_right
    walk_fastest_right
    walk_fastest_left
    walk_fastest_left
    walk_fastest_right
    walk_fastest_right
    walk_fastest_left
    walk_in_place_fastest_up
    step_end
}

movement LagoTerral_Movimiento_Hogan3 {
    walk_fastest_up
    step_end
}

movement LagoTerral_Movimiento_Hogan4 {
    walk_fast_down
    walk_fast_down
    step_end
}

movement LagoTerral_Movimiento_Cientifico2 {
    walk_down
    step_end
}

movement LagoTerral_Movimiento_Hogan5 {
    walk_fast_down * 3
    walk_fast_left
    walk_fast_down * 3
    step_end
}

movement LagoTerral_Movimiento_Prof1 {
    walk_up * 3
    walk_in_place_fast_right
    step_end
}

movement LagoTerral_Movimiento_Player1 {
    walk_up * 3
    walk_in_place_fast_left
    step_end
}

movement LagoTerral_Movimiento_Hogan6 {
    walk_fast_down * 2
    walk_fast_right
    walk_fast_down * 2
    step_end
}

movement LagoTerral_Movimiento_Prof2 {
    lock_facing_direction
    jump_left
    unlock_facing_direction
    walk_in_place_slow_down
    step_end
}

movement LagoTerral_Movimiento_Hogan7 {
    walk_fast_down * 2
    walk_in_place_fast_up
    step_end
}

movement LagoTerral_Movimiento_Prof3 {
    walk_right
    walk_in_place_down
    step_end
}

movement LagoTerral_Movimiento_Hogan8 {
    walk_fast_down
    walk_fast_down
    delay_2
    set_invisible
    walk_fast_down
    step_end
}

movement LagoTerral_Movimiento_Prof4 {
    walk_fast_up * 4
    walk_fast_left
    walk_fast_up * 4
    walk_right
    walk_up * 4
    step_end
}

movement LagoTerral_Movimiento_Player2 {
    walk_fast_left
    walk_fast_up * 4
    walk_fast_left
    walk_fast_up * 4
    walk_right
    walk_up
    step_end
}

movement LagoTerral_Movimiento_Cam1 {
    walk_fast_up * 3
    step_end
}

movement LagoTerral_Movimiento_Prof5 {
    emote_question_mark
    lock_facing_direction
    walk_fast_down
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Cientifico3 {
    walk_up
    step_end
}

movement LagoTerral_Movimiento_Cientifico4 {
    walk_down
    step_end
}

movement LagoTerral_Movimiento_Prof6 {
    lock_facing_direction
    walk_fast_down
    unlock_facing_direction
    walk_in_place_right
    walk_in_place_left
    delay_2
    walk_in_place_up
    step_end
}

movement LagoTerral_Movimiento_Cientifico5 {
    walk_right
    step_end
}

movement LagoTerral_Movimiento_Cientifico6 {
    walk_left
    step_end
}

movement LagoTerral_Movimiento_Kirlia_1 {
    walk_in_place_left
    walk_diag_southwest
    walk_in_place_down
    step_end
}

movement LagoTerral_Movimiento_Kirlia_2_1 {
    set_invisible
    walk_diag_southwest
    walk_in_place_fast_right
    set_visible
    delay_2
    set_invisible
    step_end
}

movement LagoTerral_Movimiento_Kirlia_2_2 {
    walk_diag_northeast
    walk_in_place_fast_down
    set_visible
    delay_2
    set_invisible
    step_end
}

movement LagoTerral_Movimiento_Kirlia_2_3 {
    walk_diag_southeast
    walk_in_place_fast_left
    set_visible
    delay_2
    set_invisible
    step_end
}

movement LagoTerral_Movimiento_Kirlia_2_4 {
    walk_diag_northwest
    walk_in_place_fast_down
    set_visible
    step_end
}

movement LagoTerral_Movimiento_Pooch_1 {
    jump_in_place_up
    step_end
}

movement LagoTerral_Movimiento_Pooch_2 {
    lock_facing_direction
    walk_diag_northeast
    walk_diag_southwest
    jump_in_place_up
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Kirlia_3 {
    lock_facing_direction
    walk_right
    delay_8
    walk_left
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Aparecer {
    set_visible
    delay_4
    set_invisible
    delay_4
    set_visible
    delay_4
    set_invisible
    delay_4
    set_visible
    delay_8
    set_invisible
    delay_8
    set_visible
    delay_8
    set_invisible
    delay_8
    set_visible
    delay_16
    set_invisible
    delay_16
    set_visible
    step_end
}

movement LagoTerral_Movimiento_Desaparecer {
    set_invisible
    delay_4
    set_visible
    delay_4
    set_invisible
    delay_4
    set_visible
    delay_4
    set_invisible
    delay_8
    set_visible
    delay_8
    set_invisible
    delay_8
    set_visible
    delay_8
    set_invisible
    delay_16
    set_visible
    delay_16
    set_invisible
    step_end
}

movement LagoTerral_Movimiento_Pooch_3 {
    emote_question_mark
    delay_4
    walk_right * 2
    delay_4
    walk_left * 2
    walk_fast_right
    walk_in_place_fast_up
    emote_exclamation_mark
    lock_facing_direction
    walk_fast_up
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Cientifico7 {
    walk_up * 3
    walk_in_place_down
    step_end
}

movement LagoTerral_Movimiento_Gallade_1 {
    jump_in_place_down
    step_end
}

movement LagoTerral_Movimiento_Cam2 {
    walk_fast_up * 2
    step_end
}

movement LagoTerral_Movimiento_Cientifico8 {
    walk_up * 2
    walk_in_place_down
    step_end
}

movement LagoTerral_Movimiento_Placaje_1 {
    lock_facing_direction
    //walk_up
    walk_fast_up
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Placaje_2 {
    lock_facing_direction
    walk_fastest_up
    delay_16
    walk_fastest_down
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_OndaCertera {
    lock_facing_direction
    walk_fastest_down
    delay_8
    walk_fast_up
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Damage {
    set_invisible
    delay_2
    set_visible
    delay_2
    set_invisible
    delay_2
    set_visible
    lock_facing_direction
    jump_2_down
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Cam3 {
    walk_fast_down * 2
    step_end
}

movement LagoTerral_Movimiento_Player_3 {
    emote_exclamation_mark
    delay_16
    lock_facing_direction
    walk_up
    walk_left
    walk_up * 2
    walk_right
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Cientifico_9 {
    walk_down * 2
    step_end
}

movement LagoTerral_Movimiento_Gallade_2 {
    jump_in_place_down
    set_invisible
    step_end
}

movement LagoTerral_Movimiento_Cientifico_10 {
    walk_down * 2
    step_end
}

movement LagoTerral_Movimiento_Pooch_4 {
    jump_in_place_up
    delay_4
    walk_left
    walk_up * 2
    walk_right
    walk_in_place_down
    jump_in_place_up_down
    step_end
}

movement LagoTerral_Movimiento_Pooch_5 {
    jump_in_place_down
    delay_4
    walk_left
    jump_down * 6
    step_end
}

movement LagoTerral_Movimiento_Zel_1 {
    walk_down * 5
    step_end
}

movement LagoTerral_Movimiento_Zel_2 {
    walk_down
    step_end
}

movement LagoTerral_Movimiento_Zel_3 {
    walk_down
    step_end
}

movement LagoTerral_Movimiento_Cam_4 {
    walk_fast_down * 5
    step_end
}

movement LagoTerral_Movimiento_Cam_5 {
    walk_fast_down * 10
    step_end
}

movement LagoTerral_Movimiento_Zel_4 {
    lock_facing_direction
    emote_exclamation_mark
    walk_fast_up
    unlock_facing_direction
    step_end
}

movement LagoTerral_Movimiento_Zel_5 {
    walk_down
    step_end
}

movement LagoTerral_Movimiento_Zel_6 {
    walk_right
    step_end
}

movement LagoTerral_Movimiento_Zel_7 {
    walk_left
    walk_in_place_down
    step_end
}

movement LagoTerral_Movimiento_Cam_Down {
    walk_fast_down
    step_end
}

movement LagoTerral_Movimiento_Cam_Up {
    walk_fast_up
    step_end
}
 

Juanjo

Hacker del pasado... Compilador del presente
Esto es muy importante. Hace poco andaba perdido con los scripts de nivel y como era su equivalente en decomp. Justo lo que necesitaba era un ejemplo en el cual basarme paara implementar mis scripts.

Muchas gracias por este aporte porque sé que es una excelente guía de scripts de niveles que le servira a un servidor y a los que se inicien en esta brillante aventura que es el disassembly!
 

Xiros

Creador de Pokémon Omega (2007)
Miembro del equipo
Administrador
Miembro de honor
Excelente aporte! Aún no había probado hacer un script de nivel en decomp, esto va a facilitar más cuando lo vaya a hacer.

Por cierto, fue un muy buen script!
 
Arriba