[FR](DUDA)Flag de direcciones

[Laquin]

Hola a todos, bueno, quería saber cuál es la flag de derecha\izquierda\arriba\abajo (creo que no me explico)
Por ejemplo: yo quiero que si le hablas a alguien chequee(mire, compruebe) si le has hablado por la derecha\izquierda... Sería

#org @inicio
lock
faceplayer
checkflag 0x*(la flag que busco)
if 0x1 goto @(dirección)
...
...

*quiero saber que flag es esa.
Espero que se me entienda :S
Salu2 y gracias!

 

[MegaSceptile9]

Entiendo perfectamente tu duda, pero no se utiliza el check flag sino el compare playerfacing, mira aqui un ejemplo.

'---------------
#org 0x90492E
lock
faceplayer
msgbox 0x89048BB MSG_KEEPOPEN '"¡Hola!\nSi quieres que te tome una..."
closeonkeypress
pause 0x10
compare PLAYERFACING 0x3
if 0x1 call 0x89048A7
compare PLAYERFACING 0x4
if 0x1 call 0x890489B
compare PLAYERFACING 0x1
if 0x1 call 0x890487D
applymovement 0x4 0x8904AB4
waitmovement 0x0
pause 0x15
msgbox 0x8904849 MSG_KEEPOPEN '"¡Muy bien, ahora no te muevas!\n.\..."
closeonkeypress
special 0x13D
sound 0x6
pause 0x24
msgbox 0x89047E2 MSG_KEEPOPEN '"¡Valla, quedaste muy bien en esa\n..."
release
end

'---------------
#org 0x9048A7
applymovement MOVE_PLAYER 0x89048B3
waitmovement 0x0
return

'---------------
#org 0x90489B
applymovement MOVE_PLAYER 0x8904893
waitmovement 0x0
return

'---------------
#org 0x90487D
applymovement MOVE_PLAYER 0x8904889
waitmovement 0x0
return


'---------
' Strings
'---------
#org 0x9048BB
= ¡Hola!\nSi quieres que te tome una foto\lparate a lli en frente de mi...\l.\l.\l.\p¡Ok, ve si estas listo para la\nfoto!

#org 0x904849
= ¡Muy bien, ahora no te muevas!\n.\l.\l.\p¡Di, WHISKY!

#org 0x9047E2
= ¡Valla, quedaste muy bien en esa\nfoto!\pSi quieres puedes venir las veces\nque quieras a tirarte otra.


'-----------
' Movements
'-----------
#org 0x904AB4
#raw 0x0 'Face Down
#raw 0xFE 'End of Movements

#org 0x9048B3
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0xA 'Step Left (Normal)
#raw 0x1E 'Step on the Spot Up (Normal)
#raw 0xFE 'End of Movements

#org 0x904893
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0xB 'Step Right (Normal)
#raw 0x1 'Face Up
#raw 0xFE 'End of Movements

#org 0x904889
#raw 0xB 'Step Right (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0x8 'Step Down (Normal)
#raw 0xA 'Step Left (Normal)
#raw 0x1 'Face Up
#raw 0xFE 'End of Movements

el compare, compara hacia donde esta viendo el mini a la hora de realizar el movimiento.

 

[Laquin]

Entiendo perfectamente tu duda, pero no se utiliza el check flag sino el compare playerfacing, mira aqui un ejemplo.



el compare, compara hacia donde esta viendo el mini a la hora de realizar el movimiento.

Gracias, pero me puedes decir cuál es cada uno? es decir, el 3 si es derecha\izquierda o lo que sea

 

[MegaSceptile9]

Sip, si tiene 1 creo que es cuando
el player esta mirando hacia abajo,
si tiene 2 es cuando esta mirando hacia
arriba, si tiene 3 a la izquierda (eso creo
no estoy seguro) y si tiene 4 a la
derecha (tampoco estoy seguro).

Espero haberte ayudado.

Saludos.

 

[Laquin]

Sip, si tiene 1 creo que es cuando
el player esta mirando hacia abajo,
si tiene 2 es cuando esta mirando hacia
arriba, si tiene 3 a la izquierda (eso creo
no estoy seguro) y si tiene 4 a la
derecha (tampoco estoy seguro).

Espero haberte ayudado.

Saludos.

Vale, gracias ^^ Podéis cerrar el tema

 

[Sayer301!]

dicho y hecho, tema cerrado!