FR - Tradeos Basicos

[Tahmid]

hola gentes de WaH este es mi primer publicacion despues de mirar todos los parches, rom hacks, y aportes tan fabulosos me dije a mi mismo. Voy a publicar algo. y pues ya que hice un codigo de tradeo entendible con explicacion y eso me lo pense y aqui esta os pondre las herramientas

HERRAMIENTAS
- Rom
- XSE (cualquier version si se puede utilizar claro)
- Advance Map 1.92 (es la que utilizo yo)

lo primero que vamos a usar es Advance Map y ir en eventos despues hacer un **npc, poste, evento** cualquier cosa y en offset le pondremos un 1 para editarlo en el editor (XSE) y despues pondremos este codigo











#dynamic 0x800000


'---------------
#org @main
lock '---------------bloquear
faceplayer '---------------mirar al npc
setvar 0x8008 0x0 '---------------elegir el trader (0)
call @pokemon_buscado_por_entrenador '---------------ir a script01 (determina el pokemon buscado por el entrenador)
checkflag 0x248 '---------------comprobar flag 0x248 (ya cambiado?)
if 0x1 goto @ya_cambiado '---------------si es 0x1 ir a @ya_cambiado
msgbox @busco_pokemon MSG_YESNO '"¡Busco un [buffer1]!\p¿Quieres cam..."'---------------imprimir enunciado ¿quieres cambiar? (si/no)
compare LASTRESULT 0x0 '---------------se eligió que no?
if 0x1 goto @se_eligio_no '---------------si se eligió que no --> ir a --> @se_eligio_no (salir)
call @elegir_pokemon '---------------ir a --> @elegir_pokemon
compare 0x8004 0x6 '---------------comprobar si se pulsó salir
if 0x4 goto @se_eligio_no '---------------si se pulsó salir --> @se_eligio_no (salir)
call @pokemon_elegido_por_nosotros '---------------ir a "comprobar pokemon"
comparevars LASTRESULT 0x8009 '---------------comparar ultimo resultado con 0x8009
if 0x5 goto @se_eligio_pokemon_incorrecto '---------------si no es el pkm que nos interesa-->ir a "pkm incorrecto"
call @intercambio '---------------ir a-->"pkm correcto"-->intercambio
msgbox @intercambio_completado MSG_KEEPOPEN '"¡Muchas gracias!" '---------------imprimir "muchas gracias"
setflag 0x248 '---------------cambiar flag 248
release
end

'---------------
#org @pokemon_buscado_por_entrenador
copyvar 0x8004 0x8008 '---------------0x8004 = 0x8008 (0)
special2 LASTRESULT 0xFC '---------------recoge el pokemon buscado por el entrenador
copyvar 0x8009 LASTRESULT '---------------0x8009 = resultado del special2
return '---------------regresar al main

'---------------
#org @ya_cambiado '---------------
msgbox @estupendo MSG_KEEPOPEN '"¿No es estupendo mi [buffer2]?" '--------------- imprimir "¿no es estupendo mi pokm?"
release
end

'---------------
#org @se_eligio_no
msgbox @no MSG_KEEPOPEN '"¿No?\nPues vale..." '--------------- imprimir "¿no? pues vale"
release
end

'---------------
#org @elegir_pokemon
special 0x9F '--------------- abrir menu pokemon
waitstate '--------------- esperar
lock '--------------- bloquear
faceplayer '--------------- mirar
copyvar 0x800A 0x8004 '--------------- 0x800A = 0x8004
return

'---------------
#org @pokemon_elegido_por_nosotros
copyvar 0x8005 0x800A '--------------- 0x8005 = 0x800A
special2 LASTRESULT 0xFF '--------------- recoge el pokemon elegido por nosotros
copyvar 0x800B LASTRESULT '--------------- 0x800B = LASTRESULT
return

'---------------
#org @se_eligio_pokemon_incorrecto
bufferpokemon 0x0 0x8009 '---------------
msgbox @ese_no_es MSG_KEEPOPEN '"¿Qué?\n¡Ése no es [buffer1]!" '--------------- imprimir "Qué? ese no es"
release
end

'---------------
#org @intercambio
copyvar 0x8004 0x8008 '--------------- 0x8004 = 0x8008
copyvar 0x8005 0x800A '--------------- 0x8005 = 0x800A
special 0xFD '--------------- (secuencia de
special 0xFE '--------------- intercambio pokemon)
waitstate '--------------- esperar
lock '--------------- bloquear
faceplayer '--------------- mirar
return


'---------
' Strings
'---------
#org @busco_pokemon
= ¡Busco un [buffer1]!\p¿Quieres cambiarlo por\n[buffer2]?

#org @intercambio_completado
= ¡Muchas gracias!

#org @estupendo
= ¿No es estupendo mi [buffer2]?

#org @no
= ¿No?\nPues vale...

#org @ese_no_es
= ¿Qué?\n¡Ése no es [buffer1]!




Disfruten :3 y denme creditos si se usa XDDDD los creditos no hacen falta gente y pueden editar el codigo como quieran solo es un codigo de tradeo basico y na mas

 

[Helyut]

Hola, saludos, no te digo que lo necesitaba porque yo tengo tiempo en scripteo, y ajá, pero le resultará un gran aporte para los que todavía no sepan tanto en scripting, y bueh... me despido.

¡Saludos!

PD: En donde dice [Otros] deberías poner el prefijo de [Scripts] c:

 

[Tahmid]

Hola, saludos, no te digo que lo necesitaba porque yo tengo tiempo en scripteo, y ajá, pero le resultará un gran aporte para los que todavía no sepan tanto en scripting, y bueh... me despido.

¡Saludos!

PD: En donde dice [Otros] deberías poner el prefijo de [Scripts] c:

primeramente yo tampoco sabia algo de script decia esto no es java? pues despues descubri que no es java es un lenguaje que usan los rom hackers a la hora de hacer scripts pues yo aun me considero aprendiz o novato porque no soy todo un "pro" como los demas inicie hace 6 meses y los de aqui por lo que veo estan desde 2012 y algunos mas antes pues yo flipo y igualmente gracias por tu comentario y si vere si puedo editarlo y asi lo cambio a [scripting]

 

[Helyut]

primeramente yo tampoco sabia algo de script decia esto no es java? pues despues descubri que no es java es un lenguaje que usan los rom hackers a la hora de hacer scripts pues yo aun me considero aprendiz o novato porque no soy todo un "pro" como los demas inicie hace 6 meses y los de aqui por lo que veo estan desde 2012 y algunos mas antes pues yo flipo y igualmente gracias por tu comentario y si vere si puedo editarlo y asi lo cambio a [scripting]

No eres el único nuevo aquí xD, yo estoy desde Febrero, pero cuando entré llegué con experiencia, ya que duré 3 años sin internet, intentando rom hackear a lo tostadora xDDDD.

PD: Ahora si se ve mejor con el prefijo [Script]